Livehunt uses an up-to-date version of YARA, which means that the latest YARA documentation is usually the place to go for a detailed description of the language and its features. However, there are a few things that you need to know while creating YARA rules specifically tailored for Livehunt.

• Rules for which YARA raise performance warnings are not accepted by Livehunt. Such rules are usually very slow and degrade the service both for you and the rest of the users.

• You can not use include statements in your rules.

• Standard modules currently supported are: pe, elf, math, magic, hash, cuckoo, and dotnet.

• In addition to the standard modules enumerated above, you can also the vt module, which was specifically created for Livehunt and exposes additional information about the file being scanned. Keep reading for more information about this module.

Using file's metadata in your rules

Creating rules based on file behavior

Behaviour traits

File types

Using file's metadata in your rules

Most YARA rules are based in patterns found inside the files themselves, however this is not always enough. Sometimes you may need to create rules that leverage additional information that VirusTotal has about the file. For example, you may want to create a rule that only applies to a certain file type, or files that are detected by at least one antivirus, or perhaps you are only interested in files that are submitted to VirusTotal for the first time or from a given country. All these cases, and many more, can be expressed in your YARA rules.

In order to expose all the information that VirusTotal have about the file being scanned we have created a custom YARA module named vt. This module contains metadata like antivirus signatures, file type, file behavior, submitter, etc. The vt module replaces the previous mechanism for exposing file's metadata based in custom variables like signatures, positives, file_name, and so on. These variables have been deprecated, but they will continue to work and are still documented in the Legacy variables section.

The "vt" module

The vt module exposes all the metadata that VirusTotal has about a file to YARA, so that you can create Livehunt rules based on that metadata. Let's see some examples:

import "vt"

rule infected_pe {
  condition:
    vt.metadata.analysis_stats.malicious > 1 and vt.metadata.file_type == vt.FileType.PE_EXE
}

import "vt"

rule new_file_from_china {
  condition:
    vt.metadata.new_file and vt.metadata.submitter.country == "CN"
}

import "vt"

rule zbot {
  condition:
    for any engine, signature in vt.metadata.signatures : (
      signature contains "zbot"
    )
}

From the examples above you probably already got the idea. The vt module has a lot of information about the file being scanned, and that information can be used in your Livehunt rules for filtering unwanted files and focusing in what you are really looking for. You are not limited to creating rules based on file content alone, there is a lot of metadata at your disposal as you can see in the table below.

vt.metadata.analysis_stats.malicious < 10

vt.metadata.analysis_stats.undetected > 20

vt.metadata.analysis_stats.failure > 0 

vt.metadata.analysis_stats.type_unsupported > 0

vt.metadata.exiftool["MIMEType"] == "application/pdf" and
vt.metadata.exiftool["PageCount"] == "37"

vt.metadata.first_submission_date < 1582934400 // 2020-02-29

vt.metadata.file_name contains "foobar"

vt.metadata.file_size > 100KB

vt.metadata.file_type == vt.FileType.PE_DLL

for any tag in vt.metadata.file_type_tags : (
  tag == "pedll"
)

vt.metadata.goresym.version == "1.18.7"

vt.metadata.goresym.arch == "386"

vt.metadata.goresym.os == "windows"

vt.metadata.goresym.build_id == "A_l09FDsHNuaJaKZ8MRU/H38D...HwLHCg-V/oTM-3A-yDyJSq4LWt0fu"

for any dep in vt.metadata.goresym.build_info.deps : (
  dep.path == "github.com/mattn/go-isatty" and
  dep.version == "v0.0.14"
)

vt.metadata.goresym.build_info.path == "github.com/portapps/discord-portable"

vt.metadata.goresym.build_info.settings["vcs.revision"] startswith "2f0e4453eec4"

vt.metadata.imphash == "9129bdbc18cfd1aba498c94e809567d5"

not vt.metadata.new_file 

vt.metadata.magic contains "Audio"

vt.metadata.main_icon.dhash == "00ccc4d0c4fc7c02"

vt.metadata.main_icon.raw_md5 == "997382cd5338048b70dbfbcd9b125552"

for any family_name in vt.metadata.malware_families : (
     family_name == "redline"
)

vt.metadata.md5 == "44d88612fea8a8f36de82e1278abb02f"

vt.metadata.sha256 == "275a021bbfb6489e54d471899f7db9d1663fc695ec2fe2a2c4538aabf651fd0f"

vt.metadata.sha1 == "3395856ce81f2b7382dee72602f798b642f14140"

for any engine, signature in vt.metadata.signatures : (
  engine == "Kaspersky" and signature contains ""
)

 vt.metadata.ssdeep == "3:a+JraNvsgzsVqSwHq9:tJuOgzsko"

vt.metadata.submitter.city == "madrid"

vt.metadata.submitter.country == "ES"

for any tag in vt.metadata.tags : ( tag == "signed" )

vt.metadata.telfhash == "t1992121a2ba6509a0f1fbf561b304d0450d200a1416fa36f2c275b9fadba5b820f78c37"

vt.metadata.tlsh == "T1BA45332537E1A552EB728E3053E65759CDB8B2379D66C32F3E5A100E1F72BA07D32A10"

vt.metadata.times_submitted > 5

vt.metadata.unique_sources > 3

Back to top

Creating rules based on file behavior

The vt module not only exposes information about the file itself and how it was detected by antivirus engines, it also exposes information about how the file behaves. In VirusTotal we run executable files through multiple sandboxes, which include our own in-house developed sandbox called Jujubox, and some third-party sandboxes. The behavioral information generated by all those sandboxes is normalized into a common format, and mixed together as if it was generated by a single sandbox. This aggregated behavior report is what the vt module exposes to your rule. Here you have a few examples:

import "vt"

rule drops_foo_exe {
  condition:
    for any file_dropped in vt.behaviour.files_dropped : (
      file_dropped.path contains "foo.exe"
    )
}

import "vt"

rule mutex_hgl345 {
  condition:
    for any mutex in vt.behaviour.mutexes_created : (
       mutex == "HGL345"
    )
}

import "vt"

rule persistence_and_self_deletion {
  condition:
    for any trait in vt.behaviour.traits : ( trait == vt.BehaviourTrait.PERSISTENCE ) and
    for any trait in vt.behaviour.traits : ( trait == vt.BehaviourTrait.SELF_DELETE )
}

The list below describes all the existing behaviour-related fields:

for any t in vt.behaviour.traits : (
  t == vt.BehaviourTrait.LONG_SLEEPS
) 

for any t in vt.behaviour.verdicts : (
  t == vt.BehaviourVerdict.RANSOM
) 

for any lable in vt.behaviour.verdicts_lables : (
   label contains "PDFPhish"
)

for any technique in vt.behaviour.mitre_attack_techniques : ( 
    technique.id == "t1012"
)

for any f in vt.behaviour.files_attribute_changed : (
  f contains ".exe"
)

for any f in vt.behaviours.files_copied : (
  f.source contains ".exe" and 
  f.destination contains "system32"
) 

for any c in vt.behaviour.http_conversations : (
  c.request_method == vt.Http.Method.GET
)

for any c in vt.behaviour.http_conversations : (
  c.request_headers["user-agent"] == "Moxilla"
)

for any tls_entry in vt.behaviour.tls : (
  tls_entry.sni contains "whatsapp.net"
)

for any p in vt.behaviour.permissions_requested : (
  p == "android.permission.BLUETOOTH"
)

for any cmd in vt.behaviour.command_executions : (
  cmd contains "cmd.exe /Q /c"
)

for any lib in vt.behaviour.modules_loaded : (
  lib == "zlib.dll"
) 

for any mutex in vt.behaviour.mutexes_created : (
  mutex contains "HGL345"
) 

for any s in vt.behaviour.signals_hooked : (
  s contains "WH_KEYBOARD"
) 

for any s in vt.behaviour.signals_hooked : (
  s == "android.intent.action.PROXY_CHANGE"
) 

for any svc in vt.behaviour.services_bound : (
  svc contains "gms.analytics.service.START"
) 

for any svc in vt.behaviour.services_created : (
  svc == "eckwIIMB"
)

for any key in vt.behaviour.registry_key_deleted : (
  key contains ""
)

for any r in vt.behaviour.registry_keys_set : (
  r.key matches /\\windows\\currentversion\\run/i and
  r.value contains "VMIntel386.exe"
)

for any w in vt.behaviour.windows_hidden : (
  w contains "cmd.exe /C"
)

for any w in vt.behaviour.windows_searched : (
  w contains "BANCO REAL"
) 

Back to top

HTTP methods

Network protocols

Behaviour traits

Behaviour verdicts

Back to top 

File types

Back to top 

Legacy variables

YARA offers a mechanism for defining custom variables that has been used in Livehunt for providing additional information about the file being scanned. These variables are now deprecated in favor of our custom module, but they will continue to work as always for backward compatibility. You can find list of variables defined by Livehunt below, but we highly encourage you to start using the vt module instead.

Back to top